20.5. XML Document Grammar
The Extended Backus-Naur Form (EBNF) grammar,
shown in the following section, was collected from the XML
1.0 Recommendation, Second Edition. It brings all XML
language productions together in a single location and describes the
syntax that is understood by XML 1.0-compliant parsers. Each
production has been numbered and cross-referenced using superscripted
numbers.
20.5.1. Extended Backus-Naur Form (EBNF) Grammar
20.5.1.1. Document
[1] document ::= prolog22 element39 Misc27
20.5.1.2. Character range
[2] Char ::= #x9 | #xA | #xD | [#x20-#xD7FF] | [#xE000-#xFFFD] | [#x10000-#x10FFFF]
20.5.1.3. Whitespace
[3] S ::= (#x20 | #x9 | #xD | #xA)+
20.5.1.4. Names and tokens
[4] NameChar ::= Letter84 | Digit88 | '.' | '-' | '_' | ':' | CombiningChar87 | Extender89
[5] Name ::= (Letter84 | '_' | ':') (NameChar4)*
[6] Names ::= Name5 (#x20 Name5)*
[7] Nmtoken ::= (NameChar4)+
[8] Nmtokens ::= Nmtoken7 (#x20 Nmtoken7)*
20.5.1.5. Literals
[9] EntityValue ::= '"' ([^%&"] | PEReference69 | Reference67)* '"' | "'" ([^%&'] | PEReference69 | Reference67)* "'"
[10] AttValue ::= '"' ([^<&"] | Reference67)* '"' | "'" ([^<&'] | Reference67)* "'"
[11] SystemLiteral ::= ('"' [^"]* '"') | ("'" [^']* "'")
[12] PubidLiteral ::= '"' PubidChar13* '"' | "'" (PubidChar13 - "'")* "'"
[13] PubidChar ::= #x20 | #xD | #xA | [a-zA-Z0-9] | [-'( )+,./:=?;!*#@$_%]
20.5.1.6. Character data
[14] CharData ::= [^<&]* - ([^<&]* ']]>' [^<&]*)
20.5.1.7. Comments
[15] Comment ::= '<!--' ((Char2 - '-') | ('-' (Char2 - '-')))* '-->'
20.5.1.8. Processing instructions
[16] PI ::= '<?' PITarget17 (S3 (Char2* - (Char2* '?>' Char2*)))? '?>'
[17] PITarget ::= Name5 - (('X' | 'x') ('M' | 'm') ('L' | 'l'))
20.5.1.9. CDATA sections
[18] CDSect ::= CDStart19 CData20 CDEnd21
[19] CDStart ::= '<![CDATA['
[20] CData ::= (Char2* - (Char2* ']]>' Char2*))
[21] CDEnd ::= ']]>'
20.5.1.10. Prolog
[22] prolog ::= XMLDecl23? Misc27* (doctypedecl28 Misc27*)?
[23] XMLDecl ::= '<?xml' VersionInfo24 EncodingDecl80? SDDecl32? S3? '?>'
[24] VersionInfo ::= S3 'version' Eq ("'" VersionNum26 "'" | '"' VersionNum26 '"')
[25] Eq ::= S3? '=' S3?
[26] VersionNum ::= ([a-zA-Z0-9_.:] | '-')+
[27] Misc ::= Comment15 | PI16 | S3
20.5.1.11. Document type definition
[28] doctypedecl ::= '<!DOCTYPE' S3 Name5 (S3 ExternalID)? S3? ('[' intSubset28b ']' S3?)? '>'
[28a] DeclSep ::= PEReference69 | S3
[28b] intSubset ::= (markupdecl29 | DeclSep28a)*
[29] markupdecl ::= elementdecl45 | AttlistDecl52 | EntityDecl70 | NotationDecl82 | PI16 | Comment15
20.5.1.12. External subset
[30] extSubset ::= TextDecl77? extSubsetDecl31
[31] extSubsetDecl ::= ( markupdecl29 | conditionalSect61 | DeclSep28a)*
20.5.1.13. Standalone document declaration
[32] SDDecl ::= S3 'standalone' Eq (("'" ('yes' | 'no') "'") | ('"' ('yes' | 'no') '"'))
20.5.1.14. Element
[39] element ::= EmptyElemTag44 | STag40 content43 ETag42
20.5.1.15. Start-tag
[40] STag ::= '<' Name5 (S3 Attribute)* S3? '>'
[41] Attribute ::= Name5 Eq AttValue10
20.5.1.16. End-tag
[42] ETag ::= '</' Name5 S3? '>'
20.5.1.17. Content of elements
[43] content ::= CharData14? ((element39 | Reference67 | CDSect18 | PI16 | Comment15) CharData14?)*
20.5.1.18. Tags for empty elements
[44] EmptyElemTag ::= '<' Name5 (S3 Attribute41)* S3? '/>'
20.5.1.19. Element type declaration
[45] elementdecl ::= '<!ELEMENT' S3 Name5 S3 contentspec46 S3? '>'
[46] contentspec ::= 'EMPTY' | 'ANY' | Mixed51 | children47
20.5.1.20. Element-content models
[47] children ::= (choice49 | seq50) ('?' | '*' | '+')?
[48] cp ::= (Name5 | choice49 | seq50) ('?' | '*' | '+')?
[49] choice ::= '(' S3? cp48 ( S3? '|' S3? cp48 )+ S3? ')'
[50] seq ::= '(' S3? cp48 ( S3? ',' S3? cp48 )* S3? ')'
20.5.1.21. Mixed-content declaration
[51] Mixed ::= '(' S3? '#PCDATA' (S3? '|' S3? Name5)* S3? ')*' | '(' S3? '#PCDATA' S3? ')'
20.5.1.22. Attribute-list declaration
[52] AttlistDecl ::= '<!ATTLIST' S3 Name5 AttDef53* S3? '>'
[53] AttDef ::= S3 Name5 S3 AttType54 S3 DefaultDecl60
20.5.1.23. Attribute types
[54] AttType ::= StringType55 | TokenizedType56 | EnumeratedType57
[55] StringType ::= 'CDATA'
[56] TokenizedType ::= 'ID' | 'IDREF' | 'IDREFS' | 'ENTITY' | 'ENTITIES' |
'NMTOKEN' | 'NMTOKENS'
20.5.1.24. Enumerated attribute types
[57] EnumeratedType ::= NotationType58 | Enumeration59
[58] NotationType ::= 'NOTATION' S3 '(' S3? Name5 (S3? '|' S3? Name5)* S3? ')'
[59] Enumeration ::= '(' S3? Nmtoken7 (S3? '|' S3? Nmtoken7)* S3? ')'
20.5.1.25. Attribute defaults
[60] DefaultDecl ::= '#REQUIRED' | '#IMPLIED' | (('#FIXED' S3)? AttValue10
20.5.1.26. Conditional section
[61] conditionalSect ::= includeSect62 | ignoreSect63
[62] includeSect ::= '<![' S3? 'INCLUDE' S3? '[' extSubsetDecl31 ']]>'
[63] ignoreSect ::= '<![' S3? 'IGNORE' S3? '[' ignoreSectContents64* ']]>'
[64] ignoreSectContents ::= Ignore65 ('<![' ignoreSectContents64 ']]>' Ignore65)*
[65] Ignore ::= Char2* - (Char2* ('<![' | ']]>') Char2*)
20.5.1.27. Character reference
[66] CharRef ::= '&#' [0-9]+ ';'
| '&#x' [0-9a-fA-F]+ ';'
20.5.1.28. Entity reference
[67] Reference ::= EntityRef68 | CharRef66
[68] EntityRef ::= '&' Name5 ';'
[69] PEReference ::= '%' Name5 ';'
20.5.1.29. Entity declaration
[70] EntityDecl ::= GEDecl71 | PEDecl72
[71] GEDecl ::= '<!ENTITY' S3 Name5 S3 EntityDef73 S3? '>'
[72] PEDecl ::= '<!ENTITY' S3 '%' S3 Name5 S3 PEDef74 S3? '>'
[73] EntityDef ::= EntityValue9 | (ExternalID75 NDataDecl76?)
[74] PEDef ::= EntityValue9 | ExternalID75
20.5.1.30. External entity declaration
[75] ExternalID ::= 'SYSTEM' S3 SystemLiteral11 | 'PUBLIC' S3 PubidLiteral12 S3 SystemLiteral11
[76] NDataDecl ::= S3 'NDATA' S3 Name5
20.5.1.31. Text declaration
[77] TextDecl ::= '<?xml' VersionInfo24? EncodingDecl80 S3? '?>'
20.5.1.32. Well-formed external parsed entity
[78] extParsedEnt ::= TextDecl77? content43
[79] extPE ::= TextDecl77? extSubsetDecl31
20.5.1.33. Encoding declaration
[80] EncodingDecl ::= S3 'encoding' Eq ('"' EncName81 '"' | "'" EncName81 "'" )
[81] EncName ::= [A-Za-z] ([A-Za-z0-9._] | '-')*
20.5.1.34. Notation declarations
[82] NotationDecl ::= '<!NOTATION' S3 Name5 S3 (ExternalID75 | PublicID83) S3? '>'
[83] PublicID ::= 'PUBLIC' S3 PubidLiteral12
20.5.1.35. Characters
[84] Letter ::= BaseChar85 | Ideographic86
[85] BaseChar ::= [#x0041-#x005A] | [#x0061-#x007A] | [#x00C0-#x00D6] |
[#x00D8-#x00F6] | [#x00F8-#x00FF] | [#x0100-#x0131] | [#x0134-#x013E] |
[#x0141-#x0148] | [#x014A-#x017E] | [#x0180-#x01C3] | [#x01CD-#x01F0] |
[#x01F4-#x01F5] | [#x01FA-#x0217] | [#x0250-#x02A8] | [#x02BB-#x02C1] | #x0386 |
[#x0388-#x038A] | #x038C | [#x038E-#x03A1] | [#x03A3-#x03CE] | [#x03D0-#x03D6] |
#x03DA | #x03DC | #x03DE | #x03E0 | [#x03E2-#x03F3] | [#x0401-#x040C] |
[#x040E-#x044F] | [#x0451-#x045C] | [#x045E-#x0481] | [#x0490-#x04C4] |
[#x04C7-#x04C8] | [#x04CB-#x04CC] | [#x04D0-#x04EB] | [#x04EE-#x04F5] |
[#x04F8-#x04F9] | [#x0531-#x0556] | #x0559 | [#x0561-#x0586] | [#x05D0-#x05EA] |
[#x05F0-#x05F2] | [#x0621-#x063A] | [#x0641-#x064A] | [#x0671-#x06B7] |
[#x06BA-#x06BE] | [#x06C0-#x06CE] | [#x06D0-#x06D3] | #x06D5 | [#x06E5-#x06E6] |
[#x0905-#x0939] | #x093D | [#x0958-#x0961] | [#x0985-#x098C] | [#x098F-#x0990] |
[#x0993-#x09A8] | [#x09AA-#x09B0] | #x09B2 | [#x09B6-#x09B9] | [#x09DC-#x09DD] |
[#x09DF-#x09E1] | [#x09F0-#x09F1] | [#x0A05-#x0A0A] | [#x0A0F-#x0A10] |
[#x0A13-#x0A28] | [#x0A2A-#x0A30] | [#x0A32-#x0A33] | [#x0A35-#x0A36] |
[#x0A38-#x0A39] | [#x0A59-#x0A5C] | #x0A5E | [#x0A72-#x0A74] | [#x0A85-#x0A8B] |
#x0A8D | [#x0A8F-#x0A91] | [#x0A93-#x0AA8] | [#x0AAA-#x0AB0] | [#x0AB2-#x0AB3] |
[#x0AB5-#x0AB9] | #x0ABD | #x0AE0 | [#x0B05-#x0B0C] | [#x0B0F-#x0B10] |
[#x0B13-#x0B28] | [#x0B2A-#x0B30] | [#x0B32-#x0B33] | [#x0B36-#x0B39] | #x0B3D |
[#x0B5C-#x0B5D] | [#x0B5F-#x0B61] | [#x0B85-#x0B8A] | [#x0B8E-#x0B90] |
[#x0B92-#x0B95] | [#x0B99-#x0B9A] | #x0B9C | [#x0B9E-#x0B9F] | [#x0BA3-#x0BA4] |
[#x0BA8-#x0BAA] | [#x0BAE-#x0BB5] | [#x0BB7-#x0BB9] | [#x0C05-#x0C0C] |
[#x0C0E-#x0C10] | [#x0C12-#x0C28] | [#x0C2A-#x0C33] | [#x0C35-#x0C39] |
[#x0C60-#x0C61] | [#x0C85-#x0C8C] | [#x0C8E-#x0C90] | [#x0C92-#x0CA8] |
[#x0CAA-#x0CB3] | [#x0CB5-#x0CB9] | #x0CDE | [#x0CE0-#x0CE1] | [#x0D05-#x0D0C] |
[#x0D0E-#x0D10] | [#x0D12-#x0D28] | [#x0D2A-#x0D39] | [#x0D60-#x0D61] |
[#x0E01-#x0E2E] | #x0E30 | [#x0E32-#x0E33] | [#x0E40-#x0E45] | [#x0E81-#x0E82] |
#x0E84 | [#x0E87-#x0E88] | #x0E8A | #x0E8D | [#x0E94-#x0E97] | [#x0E99-#x0E9F] |
[#x0EA1-#x0EA3] | #x0EA5 | #x0EA7 | [#x0EAA-#x0EAB] | [#x0EAD-#x0EAE] | #x0EB0 |
[#x0EB2-#x0EB3] | #x0EBD | [#x0EC0-#x0EC4] | [#x0F40-#x0F47] | [#x0F49-#x0F69] |
[#x10A0-#x10C5] | [#x10D0-#x10F6] | #x1100 | [#x1102-#x1103] | [#x1105-#x1107] |
#x1109 | [#x110B-#x110C] | [#x110E-#x1112] | #x113C | #x113E | #x1140 | #x114C |
#x114E | #x1150 | [#x1154-#x1155] | #x1159 | [#x115F-#x1161] | #x1163 | #x1165 |
#x1167 | #x1169 | [#x116D-#x116E] | [#x1172-#x1173] | #x1175 | #x119E | #x11A8 |
#x11AB | [#x11AE-#x11AF] | [#x11B7-#x11B8] | #x11BA | [#x11BC-#x11C2] | #x11EB |
#x11F0 | #x11F9 | [#x1E00-#x1E9B] | [#x1EA0-#x1EF9] | [#x1F00-#x1F15] |
[#x1F18-#x1F1D] | [#x1F20-#x1F45] | [#x1F48-#x1F4D] | [#x1F50-#x1F57] | #x1F59 |
#x1F5B | #x1F5D | [#x1F5F-#x1F7D] | [#x1F80-#x1FB4] | [#x1FB6-#x1FBC] | #x1FBE |
[#x1FC2-#x1FC4] | [#x1FC6-#x1FCC] | [#x1FD0-#x1FD3] | [#x1FD6-#x1FDB] |
[#x1FE0-#x1FEC] | [#x1FF2-#x1FF4] | [#x1FF6-#x1FFC] | #x2126 | [#x212A-#x212B] |
#x212E | [#x2180-#x2182] | [#x3041-#x3094] | [#x30A1-#x30FA] | [#x3105-#x312C] |
[#xAC00-#xD7A3]
[86] Ideographic ::= [#x4E00-#x9FA5] | #x3007 | [#x3021-#x3029]
[87] CombiningChar ::= [#x0300-#x0345] | [#x0360-#x0361] | [#x0483-#x0486] |
[#x0591-#x05A1] | [#x05A3-#x05B9] | [#x05BB-#x05BD] | #x05BF | [#x05C1-#x05C2] |
#x05C4 | [#x064B-#x0652] | #x0670 | [#x06D6-#x06DC] | [#x06DD-#x06DF] |
[#x06E0-#x06E4] | [#x06E7-#x06E8] | [#x06EA-#x06ED] | [#x0901-#x0903] | #x093C |
[#x093E-#x094C] | #x094D | [#x0951-#x0954] | [#x0962-#x0963] | [#x0981-#x0983] |
#x09BC | #x09BE | #x09BF | [#x09C0-#x09C4] | [#x09C7-#x09C8] | [#x09CB-#x09CD] |
#x09D7 | [#x09E2-#x09E3] | #x0A02 | #x0A3C | #x0A3E | #x0A3F | [#x0A40-#x0A42] |
[#x0A47-#x0A48] | [#x0A4B-#x0A4D] | [#x0A70-#x0A71] | [#x0A81-#x0A83] | #x0ABC |
[#x0ABE-#x0AC5] | [#x0AC7-#x0AC9] | [#x0ACB-#x0ACD] | [#x0B01-#x0B03] | #x0B3C |
[#x0B3E-#x0B43] | [#x0B47-#x0B48] | [#x0B4B-#x0B4D] | [#x0B56-#x0B57] |
[#x0B82-#x0B83] | [#x0BBE-#x0BC2] | [#x0BC6-#x0BC8] | [#x0BCA-#x0BCD] | #x0BD7 |
[#x0C01-#x0C03] | [#x0C3E-#x0C44] | [#x0C46-#x0C48] | [#x0C4A-#x0C4D] |
[#x0C55-#x0C56] | [#x0C82-#x0C83] | [#x0CBE-#x0CC4] | [#x0CC6-#x0CC8] |
[#x0CCA-#x0CCD] | [#x0CD5-#x0CD6] | [#x0D02-#x0D03] | [#x0D3E-#x0D43] |
[#x0D46-#x0D48] | [#x0D4A-#x0D4D] | #x0D57 | #x0E31 | [#x0E34-#x0E3A] |
[#x0E47-#x0E4E] | #x0EB1 | [#x0EB4-#x0EB9] | [#x0EBB-#x0EBC] | [#x0EC8-#x0ECD] |
[#x0F18-#x0F19] | #x0F35 | #x0F37 | #x0F39 | #x0F3E | #x0F3F | [#x0F71-#x0F84] |
[#x0F86-#x0F8B] | [#x0F90-#x0F95] | #x0F97 | [#x0F99-#x0FAD] | [#x0FB1-#x0FB7] |
#x0FB9 | [#x20D0-#x20DC] | #x20E1 | [#x302A-#x302F] | #x3099 | #x309A
[88] Digit ::= [#x0030-#x0039] | [#x0660-#x0669] | [#x06F0-#x06F9] |
[#x0966-#x096F] | [#x09E6-#x09EF] | [#x0A66-#x0A6F] | [#x0AE6-#x0AEF] |
[#x0B66-#x0B6F] | [#x0BE7-#x0BEF] | [#x0C66-#x0C6F] | [#x0CE6-#x0CEF] |
[#x0D66-#x0D6F] | [#x0E50-#x0E59] | [#x0ED0-#x0ED9] | [#x0F20-#x0F29]
[89] Extender ::= #x00B7 | #x02D0 | #x02D1 | #x0387 | #x0640 | #x0E46 | #x0EC6 |
#x3005 | [#x3031-#x3035] | [#x309D-#x309E] | [#x30FC-#x30FE]
 |  |  |
| 20.4. Constraints |  | 21. Schemas Reference |
Copyright © 2002 O'Reilly & Associates. All rights reserved.